Show Kart Statuses on Minimap [Ro]

Code:
.set region, '' #Plug in e,p,j,k for compilation region

.if (region == 'E' || region == 'e')

        .set ptr_raceData, 0x809B8F68

        .set ptr_playerBase, 0x809BD110

        .set addr_pastBattleOutlineCode, 0x807E2114

.elseif (region == 'P' || region == 'p')

        .set ptr_raceData, 0x809BD728

        .set ptr_playerBase, 0x809C18F8

        .set addr_pastBattleOutlineCode, 0x807EB9C0

.elseif (region == 'J' || region == 'j')

       .set ptr_raceData, 0x809BC788

       .set ptr_playerBase, 0x809C18F8

       .set addr_pastBattleOutlineCode, 0x807EB02C

.elseif (region == 'K' || region == 'k')

       .set ptr_raceData, 0x809ABD68

       .set ptr_playerBase, 0x809AFF38

       .set addr_pastBattleOutlineCode, 0x807D9D80

.else

        .err

.endif





getPointers:

lis r10, ptr_playerBase@ha

lwz r12, ptr_playerBase@l (r10)

lwz r12, 0x20 (r12)

cmplwi r4, 0xB

ble skipGetMasterSlot

lwz r4, ptr_raceData@l (r10)

lbz r4, 0xB84 (r4)

 skipGetMasterSlot:

mulli r11, r4, 4

add r12, r12, r11

lwz r12, 0 (r12)

lwz r12, 0 (r12)

lwz r12, 4 (r12)



calcMinimapIconSizes:

bl iconSizeDifference

.long 0x3E19999A



iconSizeDifference:

mflr r9

lwz r10, 0x1B8 (r28)

lfs f0, 0x44 (r10)

lfs f1, 0 (r9)

lwz r8, 0x1BC (r28)

lwz r9, 0x1C0 (r28)

lfs f2, 0x44 (r9)



isBigKinoko:

lwz r7, 0xC (r12)

andi. r0, r7, 0x8000

beq isThunder

fadds f0, f0, f1

fadds f2, f2, f1



isThunder:

andi. r0, r7, 0x80

beq isGesso

fsubs f0, f0, f1

fsubs f2, f2, f1



isGesso:

andis. r0, r7, 0x1000

beq storeMinimapIconXSizes

fsubs f0, f0, f0



storeMinimapIconXSizes:

stfs f0, 0x44 (r10)

stfs f2, 0x44 (r8)

stfs f2, 0x44 (r9)



isPressed:

andis. r0, r7, 0x1

beq storeMinimapIconYSizes

fsubs f0, f0, f1

fsubs f2, f2, f1

fsubs f0, f0, f1

fsubs f2, f2, f1



storeMinimapIconYSizes:

stfs f0, 0x48 (r10)

stfs f2, 0x48 (r8)

stfs f2, 0x48 (r9)



isOutlineStatus:

lwz r11, 0x8 (r12)

andis. r0, r11, 0x8000

bne outlineStarAnimation

andis. r0, r7, 0x1800

bne applyOutlines



originalInstruction:

lwz r0, 0xB90 (r3)

b end



outlineStarAnimation:

lbz r10, 0x50 (r3)

addi r10, r10, 1

cmpwi r10, 10

blt storeTimer

li r10, 0

storeTimer:

stb r10, 0x50 (r3)

cmpwi r10, 5

li r31, 2

blt applyOutlines

li r31, 1



applyOutlines:

li r0, 2

lwz r12, 0x1BC (r28)

li r11, 1

stb r11, 0xBB (r12)

lwz r12, 0x1C0 (r28)

li r11, 5

stb r11, 0xBB (r12)



branchPastBattleOutlineCodeForStarAnim:

lis r12, addr_pastBattleOutlineCode@ha

ori r12, r12, addr_pastBattleOutlineCode@l

mtctr r12

bctr



end: