Line Tracers [Skullface] - Printable Version

Code:
#============================================================#

#                           Source                           #

#------------------------------------------------------------#

# C0 Codetype                                                #

#============================================================#



.set region, '' # Put in e,p,j,k for compilation region

.set EVA_Addr, 0x0B30



# Push the Stack

stwu r1, -0x80 (r1)

stmw r2, 0x0008 (r1)



# Backup LR because C0

mflr r15



# Check if we're in a race

lis r12, 0x8151

lwz r12, 0x0000 (r12)

cmpwi r12, 0x0000

beq- the_end



lis r18, 0x8000



# KartManager_s_instance Address

.if (region == 'E' || region == 'e') # RMCE

lis r14, 0x809C

lwz r14, 0xFFFFD110 (r14)

.elseif (region == 'P' || region == 'p') # RMCP

lis r14, 0x809C

lwz r14, 0x18F8 (r14)

.elseif (region == 'J' || region == 'j') # RMCJ

lis r14, 0x809C

lwz r14, 0x0958 (r14)

.elseif (region == 'K' || region == 'k') # RMCK

lis r14, 0x809B

lwz r14, 0xFFFFFF38 (r14)

.endif



# Check if P1 Pointer is null (seems to only happen on real hardware)

cmpwi r14, 0x0000

beq- the_end



# Calculate P1 Pointer

lwz r14, 0x0020 (r14)

lwz r19, 0x1534 (r18)

add r14, r14, r19

lwz r14, 0x0000 (r14)

lwz r14, 0x0024 (r14)

lwz r14, -0x8 (r14)

lwz r14, 0x0008 (r14)

lwz r14, 0x0008 (r14)

addi r14, r14, 0x0010

addi r31, r14, 0x0068



# Check if the first pointer is a P1 Pointer

lis r28, 0x8000

ori r28, r28, EVA_Addr

li r29, 0x0000

lwzx r30, r28, r29

cmpw r30, r31

beql- fix_r30_value



# Check if we're at the end of the player pointer list

cmpwi r30, 0x0000

beq- the_end



bl call_draw_functions



loop:

addi r29, r29, 0x0004

lwzx r30, r28, r29

cmpw r30, r31

beql- fix_r30_value



# Check if we're at the end of the player pointer list

cmpwi r30, 0x0000

beq- the_end



bl call_draw_functions

b loop



fix_r30_value:

addi r29, r29, 0x0004

lwzx r30, r28, r29

cmpw r30, r31

bnelr+

b fix_r30_value



call_draw_functions:



# Backup LR

mflr r27



.if (region == 'E' || region == 'e') # RMCE

lis r12, 0x8016

ori r12, r12, 0xDB94

.elseif (region == 'P' || region == 'p') # RMCP

lis r12, 0x8016

ori r12, r12, 0xDC34

.elseif (region == 'J' || region == 'j') # RMCJ

lis r12, 0x8016

ori r12, r12, 0xDB54

.elseif (region == 'K' || region == 'k') # RMCK

lis r12, 0x8016

ori r12, r12, 0xDCD0

.endif

mtlr r12

blrl # Call GXClearVtxDesc



li r3, 0x9 # GX_VA_POS

li r4, 0x1 # GX_DIRECT

.if (region == 'E' || region == 'e') # RMCE

lis r12, 0x8016

ori r12, r12, 0xD304

.elseif (region == 'P' || region == 'p') # RMCP

lis r12, 0x8016

ori r12, r12, 0xD3A4

.elseif (region == 'J' || region == 'j') # RMCJ

lis r12, 0x8016

ori r12, r12, 0xD2C4

.elseif (region == 'K' || region == 'k') # RMCK

lis r12, 0x8016

ori r12, r12, 0xD440

.endif

mtlr r12

blrl # Call GXSetVtxDesc



li r3, 0   # GX_VTXFMT0

li r4, 0x9 # GX_VA_POS

li r5, 0x1 # GX_POS_XYZ

li r6, 0x4 # GX_F32

li r7, 0

.if (region == 'E' || region == 'e') # RMCE

lis r12, 0x8016

ori r12, r12, 0xDBC8

.elseif (region == 'P' || region == 'p') # RMCP

lis r12, 0x8016

ori r12, r12, 0xDC68

.elseif (region == 'J' || region == 'j') # RMCJ

lis r12, 0x8016

ori r12, r12, 0xDB88

.elseif (region == 'K' || region == 'k') # RMCK

lis r12, 0x8016

ori r12, r12, 0xDD04

.endif

mtlr r12

blrl # Call GXSetVtxAttrFmt



li r3, 0x1 # GX_TRUE

li r4, 0x7 # GX_ALWAYS

li r5, 0x1 # GX_TRUE

.if (region == 'E' || region == 'e') # RMCE

lis r12, 0x8017

ori r12, r12, 0x2784

.elseif (region == 'P' || region == 'p') # RMCP

lis r12, 0x8017

ori r12, r12, 0x2824

.elseif (region == 'J' || region == 'j') # RMCJ

lis r12, 0x8017

ori r12, r12, 0x2744

.elseif (region == 'K' || region == 'k') # RMCK

lis r12, 0x8017

ori r12, r12, 0x28C0

.endif

mtlr r12

blrl # Call GXSetZMode



li r3, 0x10 # Width of the lines

li r4, 0    # GX_TO_ZERO

.if (region == 'E' || region == 'e') # RMCE

lis r12, 0x8016

ori r12, r12, 0xF274

.elseif (region == 'P' || region == 'p') # RMCP

lis r12, 0x8016

ori r12, r12, 0xF314

.elseif (region == 'J' || region == 'j') # RMCJ

lis r12, 0x8016

ori r12, r12, 0xF234

.elseif (region == 'K' || region == 'k') # RMCK

lis r12, 0x8016

ori r12, r12, 0xF3B0

.endif

mtlr r12

blrl # Call GXSetLineWidth



li r3, 0xA8 # GX_LINES

li r4, 0x00 # GX_VTXFMT0

li r5, 0x02 # Amount of points

.if (region == 'E' || region == 'e') # RMCE

lis r12, 0x8016

ori r12, r12, 0xF050

.elseif (region == 'P' || region == 'p') # RMCP

lis r12, 0x8016

ori r12, r12, 0xF0F0

.elseif (region == 'J' || region == 'j') # RMCJ

lis r12, 0x8016

ori r12, r12, 0xF010

.elseif (region == 'K' || region == 'k') # RMCK

lis r12, 0x8016

ori r12, r12, 0xF18C

.endif

mtlr r12

blrl # Call GXBegin



# Get P1 X, Z, and Y and send it

lfs f0, 0x0000 (r31)

lfs f1, 0x0004 (r31)

lfs f2, 0x0008 (r31)

stfs f0, -0x8000 (r3)

stfs f1, -0x8000 (r3)

stfs f2, -0x8000 (r3)



# Get PX X, Z, and Y and send it

lfs f0, 0x0000 (r30)

lfs f1, 0x0004 (r30)

lfs f2, 0x0008 (r30)

stfs f0, -0x8000 (r3)

stfs f1, -0x8000 (r3)

stfs f2, -0x8000 (r3)



# Restore LR

mtlr r27



# Return from Call

blr



the_end:



# Restore LR because C0

mtlr r15



# Pop the Stack

lmw r2, 0x0008 (r1)

addi r1, r1, 0x0080