Auto POW Hop Dodge Bot w/ Wheelies [Ro]

Code:
Code (main code only):

stwu r1,-128(r1)

stmw r3,8(r1) # Push stack (Function call is performed in this code)

# Check if player is you

lwz r12, 0x14 (r3)            # Load value for type of player (isMaster, isCPU, isNetSend, isNetReceive etc)

andi. r12, r12, 2             # Check for isMaster (if real human local player)

beq end             # If not, skip all the code

# Check if speed is fast enough to wheelie

lis r12, 0x808B            

lfs f28, 0xB0 (r29)         # Load player speed

lfs f29, 0x1220 (r12) #        # Load wheelie speed threshold

fcmpo cr0, f28, f29            # Compare wheelie speed threshold against player speed

blt end             # If not fast enough to wheelie, skip all the code

# Check if in air

lwz r12, 4 (r3)         # Load some player statuses

rlwinm.    r0,r12,0,24,24 

bne end             # If in air, skip all the code

rlwinm. r0,r12,0,13,13 

beq end             # If in air, skip all the code

# Check if drifting

lwz r11, 4 (r3)        # Load some player statuses

lwz r12, 4 (r3)        # Load some player statuses

rlwinm r11, r12, 0, 3,3 

rlwimi. r11, r12, 0, 28, 28

bne end             # If drifting, skip all the code

# Check if Star timer is safe enough to dodge POW

lhz r12, 0x18A (r29)        # Load Star timer

cmpwi r12, 0x32

bgt end             # If timer is safe enough to dodge, skip all the code

# Check if Mega timer is safe enough to dodge POW

lhz r12, 0x194 (r29)        # Load Mega timer

cmpwi r12, 0x32

bgt end             # If timer is safe enough to dodge, skip all the code

# Check if POW Block is on the screen (POW affecting other positions but not yours)

lis r12, 0x809C

lwz r12, -0x868 (r12)        # Load POW pointer

lbz r11, 0x5D (r12)            # Load POW Block state (If on screen or not)

cmpwi r11, 0xB0

beq end             # If POW Block is not on the screen (not affecting your position), skip all the code

# Check if POW was used by you

lis r10, 0x8150

lbz r0, 0 (r10)            # Load player ID of who used POW

lbz r11, 1 (r10)        # Load your player ID    

cmpw r0, r11        # Is POW user you?

beq end             # If POW was used by you, skip all the code

# Check POW timer to do actions

lwz r12,0(r12)        # Load POW Timer

cmpwi r12, 0x49        # Is POW timer on the exact moment to wheelie?

beq wheelie            # If POW is almost hitting, start wheeling

cmpwi r12, 0x1D        # Is POW timer on the exact moment to wheelie again?

bne hop             # If POW time is not on the moment to wheelie after landing, skip to check if exact time to hop

# Call wheelie function

wheelie:

mr r3, r29

lis r12, 0x8058

ori r12, r12, 0x1B2C

mtctr r12

bctrl             # Call hop function

hop:

# Call hop function

cmpwi r12, 0x2E

bne end             # If POW is not on the exact time to hop dodge, end all the code

lwz r12, 0xC (r3)        # Load some player statuses

andi. r12, r12, 0x10        # Is wheeling?

beq end             # If not wheeling, skip all the code

mr r3, r29

lis r12, 0x8057

ori r12, r12, 0x71F8

mtctr r12 

bctrl             # Call hop function

end:

lmw r3,8(r1)

addi r1,r1,128             # Pop stack

lha r0, 0xA4 (r3)