Pretty In Game Item Spy plus Item Warning Online [Unnamed]

Code:
############################################################

############ Child count increment #########################

###### inject at 8060245c (PAL)

###### inject at 805ddb7c (NTSC-U)

######  inject at 80601bd0 (NTSC-J)

######  inject at 805f087c (NTSC-K)

lwz r5, 0x4 (r3)

cmpwi r5, 0xc # grand prix

beq increment

cmpwi r5, 0xe # 1 player offline vs

beq increment

cmpwi r5, 0x12 # 1 player battle

beq increment

cmpwi r5, 0x40 # 1 player ww/regional vs

beq increment

cmpwi r5, 0x42 # 1 player friend room vs

beq increment

b end

increment:

addi r4, r4, 0x1

end:

mr r5, r4 # original instruction





#############################################################

### Add the "GHOST DATA CANNOT BE SAVED" element  ###########

#####  inject at 808584d8 (PAL)

##### inject at 80836a48 (NTSC-U)

##### inject at 80857b44 (NTSC-J)

##### inject at 80846898 (NTSC-K)

rlwinm. r0, r16, 0x0, 19, 19 # original instruction

bne end

lwz r3, 0x4 (r15)

cmpwi r3, 0xc # grand prix

beq invert

cmpwi r3, 0xe # 1 player offline vs

beq invert

cmpwi r3, 0x12 # 1 player battle

beq invert

cmpwi r3, 0x40 # 1 player ww/regional vs

beq invert

cmpwi r3, 0x42 # 1 player friend room vs

invert:

crnot 4 * cr0 + eq, 4 * cr0 + eq

end:





#############################################################

############## Extend setTextSrc method  ####################

###### inject at 805cdd34 (PAL)

###### inject at 805c1214 (NTSC-U)

###### inject at 805cd610 (NTSC-J)

###### inject at 805bbcf4 (NTSC-K)

.set region, ''

.if (region == 'P')

        .set ptr_consts, 0x80893e70

        .set target, 0x805cde08

.elseif (region == 'E')

        .set ptr_consts, 0x8088eed0

        .set target, 0x805c12e8

.elseif (region == 'J')

        .set ptr_consts, 0x808934c0

        .set target, 0x805cd6e4

.elseif (region == 'K')

        .set ptr_consts, 0x80882280

        .set target, 0x805bbdc8

.else

        .err

.endif

# check if custom text is enabled

cmpwi r4, 0x0

bne end

# some registers are initialized in the middle of the bmg loading stuff we are skipping, so we have

# to do it here instead

lis r8, 0x4330

stw r8, 0x70 (r1)

stw r8, 0x78 (r1)

mr r18, r3

li r19, 0x0

lis r24, ptr_consts@ha

addi r24, r24, ptr_consts@l

# load the custom string

stw r5, 0x20 (r1)

li r5, 0x1

stw r5, 0x10 (r1)

# jump to the end of the bmg loading stuff

lis r5, target@h

ori r5, r5, target@l

mtlr r5

blr

end:

lwz r0, 0x0 (r4) # original instruction





#############################################################

############ Set adress, make text visible ##################

###### inject at 8057c3a8 (PAL)

###### inject at 80575b44 (NTSC-U)

###### inject at 8057bd28 (NTSC-J)

###### inject at 8056a400 (NTSC-K)

.set region, ''

.if (region == 'P')

        .set ptr_raceData, 0x809bd728

        .set ptr_menuData, 0x809c1e38

        .set ptr_unk, 0x80386000

        .set ScreenElement_setTextSrc, 0x805cdd00

.elseif (region == 'E')

        .set ptr_raceData, 0x809b8f68

        .set ptr_menuData, 0x809bd508

        .set ptr_unk, 0x80381c80

        .set ScreenElement_setTextSrc, 0x805c11e0

.elseif (region == 'J')

        .set ptr_raceData, 0x809bc788

        .set ptr_menuData, 0x809c0e98

        .set ptr_unk, 0x80385980

        .set ScreenElement_setTextSrc, 0x805cd5dc

.elseif (region == 'K')

        .set ptr_raceData, 0x809abd68

        .set ptr_menuData, 0x809b0478

        .set ptr_unk, 0x80374020

        .set ScreenElement_setTextSrc, 0x805bbcc0

.else

        .err

.endif

# get the player index of the player on which the hooked function is working

lwz r3, 0x0 (r29)

lwz r3, 0x0 (r3)

lbz r3, 0x10 (r3)

# get the player index from the first hud slot

lis r4, ptr_raceData@ha

lwz r4, ptr_raceData@l (r4)

lbz r4, 0xb84 (r4)

# if they don't match, don't update

cmpw r3, r4

bne end

# check if a single player gameplay screen is active

lis r3, ptr_menuData@ha

lwz r3, ptr_menuData@l (r3)

lwz r3, 0x0 (r3)

lwz r28, 0x38 (r3) # grand prix

cmpwi r28, 0x0

bne found

lwz r28, 0x3c (r3) # time trial

cmpwi r28, 0x0

bne found

lwz r28, 0x40 (r3) # 1 player offline vs

cmpwi r28, 0x0

bne found

lwz r28, 0x50 (r3) # 1 player battle

cmpwi r28, 0x0

bne found

lwz r28, 0x108 (r3) # 1 player ww/regional vs

cmpwi r28, 0x0

bne found

lwz r28, 0x110 (r3) # 1 player friend room vs

cmpwi r28, 0x0

bne found

b end

found:

lis r5, 0x9100 # prepare adress for displaying the string

lwz r3, 0x5c (r28)

# set the position of the hud element

lis r4, 0x4220

lis r6, ptr_unk@ha

lwz r6, ptr_unk@l (r6)

lwz r6, 0x58 (r6)

cmpwi r6, 0x1

beq widescreen

lis r4, 0x4220

widescreen:

stw r4, 0x4c (r3)

# y-position and scales

lis r4, 0xC240 # y position

stw r4, 0x50 (r3)

lis r4, 0x3f60 # x scale

stw r4, 0x58 (r3)

lis r4, 0x4020 # y scale

stw r4, 0x5c (r3)

# make the element visible

li r4, 0x0

stb r4, 0x80 (r3)

# align the text to the left

li r6, 0x0

lwz r3, 0x114 (r3)

lwz r7, 0x0 (r3)

stb r6, 0x100 (r7)

lis r12, ScreenElement_setTextSrc@h

ori r12, r12, ScreenElement_setTextSrc@l

mtctr r12

bctrl

end:

lwz r31, 0x7c (r1) # original instruction





#############################################################

############################

### inject at 80658828 #####

### inject at 80660764 #####

### inject at 8065FDD0 #####

### inject at 8064EA7C #####

############################

############################

### This adress is called right after you voted your track in online race. ##############

### We want to setup the formatted string that is called in race. All strings will be set to "unused" #############

### If a player slot is then active in race, it will be overwritten ###########

############################

stwu r1, -0x14(r1)                  ##### make small stack frame

stmw r29, 8(r1)

li r31, 0                         ####### initialize player index

player_index_loop:

mulli r12, r31, 0x28               ####### multiply player index by 40. Each player has a total amount of 20 halfwords string length

addis r12, r12, 0x9100             ####### add offset where the strings will be dumped to (0x91000000)

lis r29, 0x1a

ori r29, r29, 0x800                ###### prepare BMG escape sequence for each player

stw r29, 0(r12)                      ###### store first word of BMG escape sequence

lis r11, 0x9100 

ori r11, r11, 0x1de

lhzu r29, 2(r11)                  ###### second word contains the color (XXXX). We want to load our color from the "unused" configuration of our Tail.

addis r29, r29, 1                 ###### add the upper 0001 from the escape sequence to the color

stw r29, 4(r12)                   ###### store second word, the BMG escape sequence is now done for the player

cmpwi r31, 0xa                   ###### Now we need to setup the player slot strings, so compare the player index to 10

addi r29, r31, 0x2460

addis r29, r29, 0x2460             ###### Add the UNICODE prefix of the timer versions

blt store_player_slot             ###### If smaller than 10, we are done

addi r29, r31, 0x2456             ###### If 10 or higher, add the prefix - 10 to the index...

addis r29, r29, 0x2461            ###### ... and set the tens digit to one

store_player_slot:

stw r29, 8(r12)                  ###### store the player slot string

addi r12, r12, 0xa                ###### now prepare store adress for the UNICODE store loop

li r30, 0                        ###### initialize UNICODE_index

UNICODE_index_loop:

lhzu r29, 2(r11)                  ##### load UNICODE halfword of "unused" configuration and update adress to next halfword

sthu r29, 2(r12)                  ##### store UNICODE halfword to player slot and update adress to next halfword

addi r30, r30, 1                 ##### increment UNICODE_index

cmpwi r30, 0xd                   ###### after 13 symbols, we are done

blt UNICODE_index_loop

cmpwi r31, 0xB                   ###### one halfword left: the Newline or Null Byte, so compare player slot to 11

li r29, 0                         ##### prepare null byte 

beq store_final_player_slot_halfword 

li r29, 0xA                      ##### if not equal, replace with newline

store_final_player_slot_halfword: 

sth r29, 2(r12)                  ##### store it to last spot of player string, now we are finished for one player

addi r31, r31, 1                 ##### increment player_index

cmpwi r31, 0xC

blt player_index_loop            ##### do this for 12 players, after this we are done with setup

lmw r29, 8(r1)

addi r1, r1, 0x14

stb r8, 0x1f(r3)                 ##### default instruction





############################

### inject at 8065EE14 #####

### inject at 8065E18C #####

### inject at 8065D7F8 #####

### inject at 8064C4A4 #####

############################

############################

### Local Item Spy ASM, here we want to load the UNICODE-symbols of the items depending ############################

### on the item in inventory (NOTE: we don't need a player index here, because this subroutine is ############################

### called for each player slot (Combining local and away item spy) #########################

############################

lbz r0, 1(r3)             ##### default instruction, load the item in r0

stwu r1, -0x14(r1)        ##### make small stack frame

stmw r29, 8(r1)

cmpwi r0, 0x13

mr r11, r0                ##### copy the item to r11

blt skip_replace_nothing

li r11, 0x13              ##### if we have a 0x14 (no Item) we have to replace it with 0x13 because we want to have a fixed offset.

skip_replace_nothing:

mulli r11, r11, 0x1c      ##### multiply item by 28 to prepare the adress for the UNICODE symbols

mulli r12, r22, 0x28      ##### r22 helds player slot, so multiply player slot by 40 to prepare the store adress for the player strings

addis r11, r11, 0x9100

addi r11, r11, 0x1fa      ##### add offset of the color and the UNICODE symbols from our Tail of the current read item

addis r12, r12, 0x9100    ##### add offset of the player strings of the current player

lhzu r29, 2(r11)          ##### load the color of the current read item from our Tail...

sth r29, 6(r12)           ##### ... and store it to the correct spot of the player string

cmpwi r22, 0xa            ##### this part is for changing the timer number of your slot to normal number, what makes it easier to detect your slot in race

addi r29, r22, 0x30       ###### Add the UNICODE prefix of the normal number versions

addis r29, r29, 0x30      ###### If smaller than 10, we are done

blt store_player_slot

addi r29, r22, 0x26       ###### If 10 or higher, add the prefix - 10 to the index...

addis r29, r29, 0x31      ###### ... and set the tens digit to 1 (normal version)

store_player_slot

stw r29, 8(r12)           ###### store the player slot string, it will overwrite the timer number for your slot

addi r12, r12, 0xa        ###### now prepare store adress for the UNICODE store loop

li r31, 0                 ###### initialize UNICODE_index

UNICODE_index_loop:

lhzu r29, 2(r11)           ##### load UNICODE halfword of read item and update adress to next halfword

sthu r29, 2(r12)           ##### store UNICODE halfword to player slot and update adress to next halfword

addi r31, r31, 1           ##### increment UNICODE_index

cmpwi r31, 0xd

blt UNICODE_index_loop     ###### after 13 symbols, we are done

lmw r29, 8(r1)

addi r1, r1, 0x14





############################

### inject at 8065EE30 #####

### inject at 8065E1A8 #####

### inject at 8065D814 #####

### inject at 8064C4C0 #####

############################

############################

### Away Item Spy ASM, here we want to load the UNICODE-symbols of the items depending ############################

### on the item in inventory, NOTE: we don't need a player index here, because this subroutine is ############################

### called for each player slot (Combining local and away item spy) #########################

############################

lbz r0, 0x11(r16)              ##### default instruction, load the item in r0

stwu r1, -0x14(r1)             ##### make small stack frame

stmw r29, 8(r1)

cmpwi r0, 0x13

mr r11, r0                     ##### copy the item to r11

blt skip_replace_nothing

li r11, 0x13                   ##### if we have a 0x14 (no Item) we have to replace it with 0x13 because we want to have a fixed offset.

skip_replace_nothing:

mulli r11, r11, 0x1c           ##### multiply item by 28 to prepare the adress for the UNICODE symbols

mulli r12, r22, 0x28           ##### r22 helds player slot, so multiply player slot by 40 to prepare the store adress for the player strings

addis r11, r11, 0x9100

addi r11, r11, 0x1fa           ##### add offset of the color and the UNICODE symbols from our Tail of the current read item

addis r12, r12, 0x9100         ##### add offset of the player strings of the current player

lhzu r29, 2(r11)               ##### load the color of the current read item from our Tail...

sth r29, 6(r12)                ##### ... and store it to the correct spot of the player string

addi r12, r12, 0xa             ###### now prepare store adress for the UNICODE store loop

li r31, 0                      ###### initialize UNICODE_index

UNICODE_index_loop:

lhzu r29, 2(r11)               ##### load UNICODE halfword of read item and update adress to next halfword

sthu r29, 2(r12)               ##### store UNICODE halfword to player slot and update adress to next halfword

addi r31, r31, 1               ##### increment UNICODE_index

cmpwi r31, 0xd

blt UNICODE_index_loop         ###### after 13 symbols, we are done

lmw r29, 8(r1)

addi r1, r1, 0x14