Load Savebanner Text from BMG [ArcticLuma113]

Code:
# Second part.

# Inject at:

#   0x8064c750 (USA)

#   0x80637a88 (PAL)

#   0x80637174 (JAP)

#   0x80625e20 (KOR)



.if region == 'e'

 .set DVDOpen, 0x8015e21c # USA

 .set DVDRead, 0x8015e794 # USA

 .set DVDClose, 0x8015e4c8 # USA

 .set ParseBMG, 0x805d831c # USA

.elseif region == 'p'

 .set DVDOpen, 0x8015e2bc # PAL

 .set DVDRead, 0x8015e834 # PAL

 .set DVDClose, 0x8015e568 # PAL

 .set ParseBMG, 0x805f8c00 # PAL

.elseif region == 'j'

 .set DVDOpen, 0x8015e1dc # JAP

 .set DVDRead, 0x8015e754 # JAP

 .set DVDClose, 0x8015e488 # JAP

 .set ParseBMG, 0x805f84dc # JAP

.elseif region == 'k'

 .set DVDOpen, 0x8015e334 # KOR

 .set DVDRead, 0x8015e8ac # KOR

 .set DVDClose, 0x8015e5e0 # KOR

 .set ParseBMG, 0x805e7020 # KOR

.else

 .err

.endif

.set BMGBuf, 0x80003200



# in: r6 - Sysconf language (PAL/NTSC-U only), r4 - original BMG address

# out: r4 - BMG address



# r0 isn't set or checked in Japanese or Korean games, so set them now.

# TODO: Load up Sysconf ourselves in this case

.if region == 'j'

li r0, 0

.elseif region == 'k'

li r0, 9

.else # America and Europe

mr r0, r6 # Part 1 above sets r6

.endif



# Set up stack buffer:

# 0x8 - stack frame

# 0x18 - 3 registers and 3 extra pointers

# 0x40 - DVDFileInfo struct

stwu sp, -0x60(sp)

stmw r29, 8(sp)

mflr r29 # TODO: are these two instructions really necessary? (Likely needed as a place for ParseBMG to come back to once it's done)

stw r29, 0x60(sp)

# back up registers needed for DVDOpen/DVDRead arguments

mr r29, r3

mr r30, r7

mr r31, r8

# back up pointer to original BMG

stw r4, 0x14(sp)

# get address of the file name

bl file

.asciz "/Boot/save?.bmg"

.balign 4

file:

mflr r3

# check sysconf language

li r4, 0x43

cmpwi r0, 7 # C

beq _after

addi r4, r4, 2

cmpwi r0, 1 # E

beq _after

addi r4, r4, 1

cmpwi r0, 3 # F

beq _after

addi r4, r4, 1

cmpwi r0, 2 # G

beq _after

addi r4, r4, 2

cmpwi r0, 5 # I

beq _after

addi r4, r4, 1

cmpwi r0, 0 # J

beq _after

addi r4, r4, 1

cmpwi r0, 9 # K

beq _after

addi r4, r4, 3

cmpwi r0, 6 # N

beq _after

addi r4, r4, 5

cmpwi r0, 4 # S

beq _after

addi r4, r4, 4

cmpwi r0, 8 # W

beq _after

li r4, 0x45

_after:

stb r4, 10(r3)

addi r4, sp, 0x20

stw r4, 0x18(sp)

# Call DVDOpen

# r3: File name r4: DVDFileInfo*

lis r6, DVDOpen@h

ori r6, r6, DVDOpen@l

mtlr r6

blrl

cmpwi r3, 0

beq _fail2 # TODO: better way?

# Check    if the file size is >= 0x400

lwz r4, 0x18(sp)

lwz r5, 52(r4)

cmpwi r5, 0x400

bge _fail # too big

# Call DVDRead

# r3: DVDFileInfo* r4: dest buffer r5: size r6: offset r7: unknown, assumed constant 2

mr r3, r4

lis r4, BMGBuf@h

ori r4, r4, BMGBuf@l

stw r4, 0x1c(sp)

li r6, 0

li r7, 2

lis r8, DVDRead@h

ori r8, r8, DVDRead@l

mtlr r8

blrl

cmpwi r3, 0

blt _fail # TODO: better way?

lwz r4, 0x1c(sp)

# Check if we really got a BMG file

lis r3, 0x4d45

ori r3, r3, 0x5347

lwz r5, 0(r4)

cmpw r5, r3

beq _success

_fail:

lwz r4, 0x14(sp)

_success:

# close the file

# r3: DVDFileInfo*

lwz r3, 0x18(sp)

lis r5, DVDClose@h

ori r5, r5, DVDClose@l

mtlr r5

blrl

lwz r4, 0x1c(sp)

b _cleanup

_fail2:

lwz r4, 0x14(sp)

_cleanup:

# Reset changed registers (other than r5 and r6, they're set later anyways)

mr r8, r31

mr r7, r30

mr r3, r29

lmw r29, 8(sp)

# TODO: are these two instructions necessary also?

# Better safe than sorry I guess. The BMG parser needs to know where to return to.

# Also at this point, r6 is safe to use as it's written to by said parser.

lwz r6, 0x60(sp)

mtlr r6

addi sp, sp, 0x60

# Default instruction is a branch, so we jump directly to the BMG parser

lis r6, ParseBMG@h

ori r6, r6, ParseBMG@l

mtctr r6

bctr