Boot into TT cup selection screen [Melg]

Code:

#1st ASM

#inject(0x805b9368)\n\n (PAL)

#inject(0x8061F85C)\n\n (NTSC-U)

#inject(0x805B8CE8)\n\n (NTSC-J)

#inject(0x805A73C0)\n\n (NTSC-K)

.set region, 'P' #Must set region value, or else source will not compile

.if (region == 'P')

    .set RACEDATA, 0x809bd728

    .set MENUDATA, 0x809c1e38  

.elseif (region == 'E')

    .set RACEDATA, 0x809b8f68

    .set MENUDATA, 0x809bd508

.elseif (region == 'J')

    .set RACEDATA, 0x809bc788

    .set MENUDATA, 0x809c0e98

.elseif (region == 'K')

    .set RACEDATA, 0x809abd68

    .set MENUDATA, 0x809B0478

.else

  .err

.endif



#Args: r3 = SystemManager::StaticInstance

#We boot into menu 0x4A, which is single player coming from TT change course. The first screen displayed by that menu is obviously, the course selection, so by booting into this menu we effectively boot into that screen.

#Initiate all the values that aren't because we boot directly into the course selection.



lis r28, RACEDATA@ha

lwz r4, RACEDATA@l (r28)

addi r4, r4, 0xC18  #Get into scenario[1], each player array is 0xF0 bytes long

li r5, 0x2          #Gamemode = TT

stw r5, 0xB44 (r4)  



addi r5, r4, 0x10   #Align with PlayerType of RaceData->main.scenario[1].players[0]

li r0, 0x5          #PlayerType = None

li r6, 0xB          #Slot 0 is an actual player, so only 11 PlayerType to fill



Loop: 

stwu r0, 0xF0 (r5)  #Store the PlayerType, and update r5 to the next RaceData->main.scenario[1].players

subic. r6, r6, 1

bne+ Loop



li r5, 0x17         #Vehicle ID

li r6, 0x16         #Character ID, both of these used to choose which combo you get in race

stw r5, 0x8 (r4)

stw r6, 0xC (r4)



lwz r4, MENUDATA@l (r28)

lwz r4, 0x98 (r4)

stw r5, 0x13C (r4)  #Same but this type for the combo displayed in the menus

stw r6, 0x12C (r4)





bl string

.string "-s132 -l0 -p292"  #-p set to GCN just for compiling purposes; you can get the decimal values by converting the ASCIII strings provided above

.byte 00

.align 2

string:

mflr r28

stw r28, 0x98 (r3)         #Store pointer to string, which will be used by the function later; the default instruction is lwz r28 from the same address. If that address does not contain a pointer, the game boots as it usually would. So we both store in memory and load the value into r28 in one instruction.

Code:

#inject(0x805243dc)\n\n (PAL)

#inject(0x8051FF68)\n\n (NTSC-U)

#inject(0x80523D5C)\n\n (NTSC-J)

#inject(0x80512400)\n\n (NTSC-K)



.set region, 'P' #Must set region value, or else source will not compile

.if (region == 'P')

    .set MENUDATA, 0x809c1e38  

.elseif (region == 'E')

    .set MENUDATA, 0x809bd508

.elseif (region == 'J')

.set MENUDATA, 0x809c0e98

.elseif (region == 'K')

    .set MENUDATA, 0x809B0478

.else

  .err

.endif



#Fixes controller not being properly initiated since we skip the title screen "Press A". Stores the correct InputData substruct pointers depending on the controller. Without this, the correct controller buttons are displayed but the game does not fetch the inputs from the right place.

#r30 = INPUTDATA



lis r3, MENUDATA@ha

lwz r3, MENUDATA@l (r3)

lbz r4, 0x3B (r3)             #Get the controllerType from MenuDataSub

cmpwi r4, 0x24              #Check if it's a GCN

addi r4, r30, 0x1720

li r5, 0x920  

bne+ end

addi r4, r30, 0x3ba0

li r5, 0xB0

end:

lbz r3, 0x3A (r3)            #Get the slot

subi r3, r3, 0x1

mullw r3, r3, r5    

add r4, r4, r3                #Correct pointer depending on controller and slot