Track Music Expander [CLF78] - Printable Version

Code:
# Hook = 0x8009E0BC PAL, 0x8009E01C NTSC-U, 0x8009DFDC NTSC-J, 0x8009E11C NTSC-K



# Address Ports

.set region, ''

.if (region == 'P' || region == 'p')

 .set ctcodething, 0x80000DF4

 .set sprintf, 0x80011A2C

 .set DVDConvertPathToEntrynum, 0x8015DF4C

 .set lecodething, 0x80553E08

.elseif (region == 'U' || region == 'u' || region == 'E' || region == 'e')

 .set ctcodething, 0x80000DF4

 .set sprintf, 0x80010ECC

 .set DVDConvertPathToEntrynum, 0x8015DEAC

 .set lecodething, 0x8054DDE8

.elseif (region == 'J' || region == 'j')

 .set ctcodething, 0x80000DF4

 .set sprintf, 0x80011950

 .set DVDConvertPathToEntrynum, 0x8015DE6C

 .set lecodething, 0x80553788

.elseif (region == 'K' || region == 'k')

 .set ctcodething, 0x80000DF4

 .set sprintf, 0x80011A94

 .set DVDConvertPathToEntrynum, 0x8015DFC4

 .set lecodething, 0x80541E60

.else

 .err

.endif



# Track Expansion Mod Type (c = CT-CODE, l = LE-CODE)

.set game, ''

.if (game != 'l' && game != 'c')

 .err

.endif



# Check if we are loading a track song by checking the file's first character

lbz r3, 0x15C(r1)



cmpwi r3, 'n'

beq+ isTrack



cmpwi r3, 'S'

beq+ isTrack



cmpwi r3, 'r'

bne originalTrack



# Get the track slot from the exception vector

isTrack:

.if (game == 'c')

 lis r6, ctcodething@ha

 lwz r6, ctcodething@l(r6)



# Get the instruction from the lecode address and branch to it, slot is returned in r4

.elseif (game == 'l')

 lis r3, lecodething@h

 ori r3, r3, lecodething@l

 lwz r4, 0(r3)

 rlwinm r4, r4, 0, 6, 29

 add r3, r3, r4

 mtctr r3

 bctrl

 mr r6, r4

.endif



# Do bl trick

bl trick



# Main format string

.string "%sstrm/%03x%s.brstm"



# Last lap string

.string "_F"

.align 2



# Set main format string

trick:

mflr r4



# Set root path

addi r5, r29, 0x8



# Set last lap string

addi r7, r4, 0x14



# Load last character of filename before the extension

addi r8, r28, 0x150

lbzx r8, r8, r1



# Check for an F either lower or uppercase

cmpwi r8, 'f'

beq isFast



cmpwi r8, 'F'

beq isFast



# Add two to fast lap string if not fast

addi r7, r7, 2



# String buffer (this part of the stack is no longer used at this point in the function)

isFast:

addi r3, r1, 0x24



# Call sprintf

lis r12, sprintf@h

ori r12, r12, sprintf@l

mtctr r12

bctrl



# Call DVDConvertPathToEntrynum

addi r3, r1, 0x24

lis r12, DVDConvertPathToEntrynum@h

ori r12, r12, DVDConvertPathToEntrynum@l

mtctr r12

bctrl



# Check if file exists

cmpwi r3, -1

beq originalTrack



# It does, we can use this path!

addi r26, r1, 0x24

b end



# Original instruction

originalTrack:

addi r26, r1, 0x150



# Return

end: