Rejoin Room [TheLordScruffy] - Printable Version

Code:
#define REGION 'P' /* Define a region RMC? */

#define BMG_PATCH /* Patch text with text in the code */

#define DRIFT_HELP_BUTTON /* Use the "DriftHelp" button style and position on the menu */

#define TOUCH_PANE_PATCH /* Patch the touch pane to make the DriftHelp button selectable */

#define INVISIBLE_BUTTON /* Only show the button if you have a room to rejoin */

#define CHECK_WW /* Enable a check if the Worldwide button exists */





#if REGION == 'E'

#define PORT(E, J, P, K) E

#elif REGION == 'J'

#define PORT(E, J, P, K) J

#elif REGION == 'P'

#define PORT(E, J, P, K) P

#elif REGION == 'K'

#define PORT(E, J, P, K) K

#else

#define PORT(E, J, P, K) 0

#endif





#define GCT_WRITE_8(ADDRESS, VALUE) \

    .long 0x00000000 | (ADDRESS & 0x1FFFFFF); \

    .long (VALUE & 0xFF)



#define GCT_FILL_8(ADDRESS, VALUE, COUNT) \

    .long 0x00000000 | (ADDRESS & 0x1FFFFFF); \

    .long (VALUE & 0xFF) | ((COUNT + 1) << 16)



#define GCT_WRITE_16(ADDRESS, VALUE) \

    .long 0x02000000 | (ADDRESS & 0x1FFFFFF); \

    .long (VALUE & 0xFFFF)



#define GCT_FILL_16(ADDRESS, VALUE, COUNT) \

    .long 0x02000000 | (ADDRESS & 0x1FFFFFF); \

    .long (VALUE & 0xFFFF) | ((COUNT + 1) << 16)



#define GCT_WRITE_32(ADDRESS, VALUE) \

    .long 0x04000000 | (ADDRESS & 0x1FFFFFF); \

    .long VALUE



#define GCT_WRITE_STRING(ADDRESS, STRING) \

    .long 0x06000000 | (ADDRESS & 0x1FFFFFF); \

    .long string_##ADDRESS##_size; \

string_##ADDRESS:; \

    .string STRING; \

    .set string_##ADDRESS##_size, . - string_##ADDRESS; \

    .align 3



#define GCT_STRING(NAME, ADDRESS) \

    .long 0x06000000 | (ADDRESS & 0x1FFFFFF); \

    .long NAME##_size; \

NAME:;

#define GCT_STRING_END(NAME) \

    .set NAME##_size, . - NAME; \

    .align 3



#define GCT_EXECUTE(NAME) \

    .long 0xC0000000; \

    .long (NAME##_size + 1) >> 3; \

NAME:

#define GCT_EXECUTE_END(NAME) \

    .align 3; \

    .set NAME##_size, . - NAME



#define GCT_INSERT(ADDRESS, NAME) \

    .long 0xC2000000 | (ADDRESS & 0x1FFFFFF); \

    .long (NAME##_size + 1) >> 3; \

    .set NAME##_start, .

#define GCT_INSERT_END(NAME) \

    nop; \

    .align 3; \

    .set NAME##_size, . - NAME##_start



#define GCT_WRITE_BRANCH(SRC, DEST) \

    .long 0xC6000000 | (SRC & 0x1FFFFFF); \

    .long DEST







#define B_CALL(ADDRESS) \

.ifdef asm_call_thunk; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    b asm_call_thunk; \

.else; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    mtctr r12; \

    bctr; \

.endif



#define BL_CALL(ADDRESS) \

.ifdef asm_call_thunk; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    bl asm_call_thunk; \

.else; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    mtctr r12; \

    bctrl; \

.endif



#define BC_CALL(CONDITION, ADDRESS) \

.ifdef asm_call_thunk; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    b##CONDITION- asm_call_thunk; \

.else; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    mtctr r12; \

    b##CONDITION##ctr-; \

.endif



#define BCL_CALL(CONDITION, ADDRESS) \

.ifdef asm_call_thunk; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    b##CONDITION##l- asm_call_thunk; \

.else; \

    lis r12, (ADDRESS)@h; \

    ori r12, r12, (ADDRESS)@l; \

    mtctr r12; \

    b##CONDITION##ctr##l-; \

.endif



#define STRING(REG, STRING, SYM) \

    bl str_##SYM##_end; \

str_##SYM:; \

    .string STRING; \

    .align 2; \

    str_##SYM##_end:; \

    mflr REG



#define SHORT_PTR(REG, SYM, DATA...) \

    bl short_##SYM##_end; \

short_##SYM:; \

    .short DATA; \

    .align 2; \

    short_##SYM##_end:; \

    mflr REG



#define FLOAT_PTR(REG, SYM, DATA...) \

    bl short_##SYM##_end; \

short_##SYM:; \

    .float DATA; \

    .align 2; \

    short_##SYM##_end:; \

    mflr REG



#define PTR(REG, NAME) \

    bl 4; \

    mflr REG; \

    addi REG, REG, (NAME) - (. - 4)



#define PTR_LWZ(REG, NAME, INDEX) \

    bl 4; \

    mflr REG; \

    lwz REG, (NAME) - (. - 4) + INDEX(REG)



#define PTR_LBZ(REG, NAME, INDEX) \

    bl 4; \

    mflr REG; \

    lbz REG, (NAME) - (. - 4) + INDEX(REG)



#define PTR_LWZU(REG, TMP_REG, NAME, INDEX) \

    bl 4; \

    mflr TMP_REG; \

    lwzu REG, (NAME) - (. - 4) + INDEX(TMP_REG)



#define PTR_LBZU(REG, TMP_REG, NAME, INDEX) \

    bl 4; \

    mflr TMP_REG; \

    lbzu REG, (NAME) - (. - 4) + INDEX(TMP_REG)



#define PTR_STW(REG, TMP_REG, NAME, INDEX) \

    bl 4; \

    mflr TMP_REG; \

    stw REG, (NAME) - (. - 4) + INDEX(TMP_REG)



#define PTR_STWU(REG, TMP_REG, NAME, INDEX) \

    bl 4; \

    mflr TMP_REG; \

    stwu REG, (NAME) - (. - 4) + INDEX(TMP_REG)



/* E, J, P, K addresses */

/* operator new(unsigned long), or rather, malloc */

.set __nw__FUl,                    PORT( 0x80229A48, 0x80229CEC, 0x80229DCC, 0x8022A140 )

/* Menu stuff */

.set Menu_Control_Construct,       PORT( 0x805B5704, 0x805BCD28, 0x805BD3A8, 0x805AB400 )

.set Menu_Control_LoadLayout,      PORT( 0x805B5874, 0x805BCE98, 0x805BD518, 0x805AB570 )

.set Menu_Control_SetAllText,      PORT( 0x8060C994, 0x8063D420, 0x8063DDB4, 0x8062C0CC )

.set Menu_Screen_InitControlList,  PORT( 0x805DDB7C, 0x80601BD0, 0x8060245C, 0x805F087C )

.set Menu_Screen_InsertControl,    PORT( 0x805DDB8C, 0x80601BE0, 0x8060246C, 0x805F088C )

.set Menu_Screen_ShowOnTop,        PORT( 0x805DDCD0, 0x80601D24, 0x806025B0, 0x805F09D0 )

/* Not 100% sure if the following two have the most accurate names */

.set Menu_Control_GetTransTimer,   PORT( 0x805B62E4, 0x805BD908, 0x805BDF88, 0x805ABFE0 )

.set Menu_Screen_StartTransition,  PORT( 0x805DDBA8, 0x80601BFC, 0x80602488, 0x805F08A8 )

/* GetTransTimer (shortened from GetTransitionTimer) returns a float of the amount of time

/  to wait before transitioning to the next screen. */

/* StartTransition starts the screen transition after the amount of time, passed as f1, is

/  over. The main way to use this is to pass on the value from Menu_Control_GetTransTimer. */

.set Menu_Mesg_MIDToIndex,         PORT( 0x805D83A4, 0x805F8564, 0x805F8C88, 0x805E70A8 )

.set Menu_HeaderText_SetText,      PORT( 0x80841960, 0x807E90A4, 0x807E9A38, 0x807D7DF8 )

/* I really dislike the "MenuData" name */

.set MenuData,                     PORT( 0x809BD508, 0x809C0E98, 0x809C1E38, 0x809B0478 )

.set SearchManager_SetGameMode,    PORT( 0x805E53E4, 0x8060942C, 0x80609CB8, 0x805F80D8 )

.set RKNetController_JoinFriend,   PORT( 0x806551F8, 0x80658CEC, 0x80659680, 0x80647998 )

.set RKNetController_SetupWWVS,    PORT( 0x80651D2C, 0x80655820, 0x806561B4, 0x806444CC )

.set RKNetController_sInstance,    PORT( 0x809BD918, 0x809C1138, 0x809C20D8, 0x809B0718 )



/* Some useful stuff */

.set button_str,                   PORT( 0x8089219F, 0x80898B8F, 0x80899A2F, 0x80887E67 )

.set WifiMenuSingleTop_str,        PORT( 0x808921A6, 0x80898B96, 0x80899A36, 0x80887E6E )

.set wifi_button_vtable,           PORT( 0x808B9904, 0x808BF104, 0x808BFFB4, 0x808AE424 )



#define REJOIN 4 /* SearchManager search mode */

#define REJOIN_MODE 11 /* RKNetController join mode */





/* Fix bottom text for highlighting Rejoin */

GCT_INSERT(PORT(0x80618C5C, 0x8064B5DC, 0x8064BF70, 0x8063A288), rejoin_bottom_text)

    cmpwi r0, 6

    bnelr-



    li r4, 4006

    //li r5, 0

    addi r3, r3, 2968

    lis r12, Menu_HeaderText_SetText@h

    ori r12, r12, Menu_HeaderText_SetText@l



/* This thunk to optimize call size is why we need this insert first */

asm_call_thunk:

    mtctr r12

    bctr

GCT_INSERT_END(rejoin_bottom_text)





/* Misc data and functions for use.

/  Could probably use goto instead of C0 + blr to do this. */

GCT_EXECUTE(data)

    blr



#if 0

/* Temporary location string to save to */

rejoin_location_temp:

    .long 0x00000000 // Group ID

    .byte 0xFF // Region ID

    .byte 0x00 // Status

    .byte 0x00 // Player count

    .byte 0x00 // Race count

#endif



/* Last room location string */

rejoin_location:

    .long 0x00000000 // Group ID

    .byte 0xFF // Region ID

    .byte 0x00 // Status

    .byte 0x00 // Player count

    .byte 0x00 // Race count



button_select_data:

    .long wifi_button_vtable

    .long 0

    .long 0

    .long -1

    .long 0



/* Function for pressing the Reconnect button */

rejoin_button_press_event:

    mflr r0

    stwu sp, -0x20(sp)

    stw r0, 0x24(sp)

    stmw r28, 0x20-0x10(sp)

    mr r31, r3 // wifi top screen

    mr r29, r4 // Rejoin button



    lis r3, MenuData@ha

    lwz r3, MenuData@l(r3)

    lwz r28, 0(r3)



    /* r12 is always a pointer to rejoin_button_press_event */

    lwz r5, rejoin_location - rejoin_button_press_event(r12)

    cmpwi r5, 0

    beq+ rejoin_button_display_msgbox

    

    /* Continue onward with rejoining room */

    lwz r3, 0x244(r28) // Screen 0x8F pointer



    /* Set the mode to 4 so we know we're rejoining a room */

    li r4, REJOIN

    stw r4, 0x1CF4(r3)



    lbz r5, rejoin_location - rejoin_button_press_event + 5(r12)



    li r4, 0 // VS

    cmpwi r5, 0x05

    beq+ rejoin_button_gamemode_label



    li r4, 1 // Battle

    cmpwi r5, 0x08

    bne- rejoin_button_display_msgbox



rejoin_button_gamemode_label:

    BL_CALL(SearchManager_SetGameMode)



    /* Setup screen transition */

    li r0, 0x8F // SearchManager screen ID

    stw r0, 0xF30(r31)



    mr r3, r29

    BL_CALL(Menu_Control_GetTransTimer)

    mr r3, r31

    li r4, 0

    BL_CALL(Menu_Screen_StartTransition)

    b rejoin_button_press_event_end



rejoin_button_display_msgbox:

    lwz r3, 0x13C(r28)

    addi r3, r3, 424

    li r4, 0xFB1

    //li r5, 0

    BL_CALL(Menu_Control_SetAllText)



    mr r3, r31

    li r4, 0x4D

    li r5, 0

    BL_CALL(Menu_Screen_ShowOnTop)



rejoin_button_press_event_end:

    lwz r0, 0x24(sp)

    mtlr r0

    lmw r28, 0x20-0x10(sp)

    addi sp, sp, 0x20

    blr





#ifdef BMG_PATCH

/* wifi_rejoin_button functions */

#define BMG_STRING(MID) (MID - bmg_strings)

bmg_strings:

mid_0xFA5:

.string "Rejoin"

mid_0xFA6:

.string "Rejoin the last room you played."

#ifndef INVISIBLE_BUTTON

mid_0xFB1:

.string "You have not played\na room to rejoin."

#endif

mid_0xFB7:

.string "You were unable to\nrejoin the room.\n\nPlease wait and try\nagain later."

mid_0x1009:

.string "Rejoining room..."

.align 2

.set bmg_strings_size, . - bmg_strings



get_mid_index_func:

    addi r3, r30, 0xF34 + 0x144

    B_CALL(Menu_Mesg_MIDToIndex)



overwrite_mid_func:

    cmpwi r3, -1

    beqlr- // MID doesn't exist



    /* This could probably be much more optimized */

    mflr r12

    PTR(r5, bmg_strings - 1)

    slwi r6, r4, 1

    addi r7, r30, 0xF34 + 0x254

    add r8, r7, r6

    subi r7, r8, 2

    add r5, r5, r4



overwrite_mid_loop:

    lbzu r4, 1(r5)

    sthu r4, 2(r7)

    cmpwi r4, 0

    bne+ overwrite_mid_loop

    mtlr r12

    

    lwz r5, 0xF34 + 0x144 + 4(r30)

    lwz r6, 0xF34 + 0x144 + 8(r30)

    slwi r0, r3, 3

    add r5, r5, r0



    lwz r7, 8(r5)

    lhzx r0, r7, r6

    cmpwi r0, 0

    bnelr- // MID is not blank, so we will not overwrite it



    subf r6, r6, r8

    stw r6, 8(r5) // Hacky file offset overwrite

    blr

#endif



#ifdef CHECK_WW

control_count:

    .long 7 // Control count

#endif



GCT_EXECUTE_END(data)



/* Create memory for the new button */

GCT_WRITE_32(PORT(0x805F3198, 0x80623798, 0x8062404C, 0x80612444),

#ifdef BMG_PATCH

    0x38600F34 + 0x254 + bmg_strings_size*2

#else

    0x38600F34 + 0x254

#endif

)



/* Update control count */

#ifndef CHECK_WW

GCT_WRITE_32(PORT(0x8061866C, 0x8064AFEC, 0x8064B980, 0x80639C98), 0x38800007);

#else

GCT_INSERT(PORT(0x80618670, 0x8064AFF0, 0x8064B984, 0x80639C9C), update_control_count)

    PTR_STW(r4, r9, control_count, 0)

    addi r4, r4, 1

    BL_CALL(Menu_Screen_InitControlList)

GCT_INSERT_END(update_control_count)

#endif



/* Construct new button on WFC menu top */

GCT_INSERT(PORT(0x806188F4, 0x8064B274, 0x8064BC08, 0x80639F20), wifi_rejoin_button)

    /* Construct the button */

    addi r3, r30, 0xF34

    BL_CALL(Menu_Control_Construct)



    mr r3, r30 // Screen class

#ifndef CHECK_WW

    li r4, 6 // Control ID

#else

    PTR_LWZ(r4, control_count, 0)

#endif

    addi r5, r30, 0xF34 // Control class

    li r6, 0 // ?

    BL_CALL(Menu_Screen_InsertControl)



    addi r3, r30, 0xF34

    lis r5, button_str@h

    ori r4, r5, button_str@l // Base folder

#ifndef DRIFT_HELP_BUTTON

    /* Use the unused ButtonGhostBattle element */

    ori r5, r5, WifiMenuSingleTop_str@l // bctrl name

    STRING(r6, "ButtonGhostBattle", btn_name) // bctrl element name

#else

    STRING(r6, "DriftHelp", btn_name) // bctrl element name

    mr r5, r6

#endif

    li r7, 1 // ?

    li r8, 0 // ?

    li r9, 0 // 1 if only selectable by wiimote pointer

    BL_CALL(Menu_Control_LoadLayout)



#ifdef DRIFT_HELP_BUTTON

#ifdef TOUCH_PANE_PATCH

    /* By default the new button wouldn't be selectable because the "touch" panes,

       the panes that decide where the cursor needs to be to select the button,

       of the Worldwide/Regional buttons are too big.

       The Friends button's "touch" is actually a little smaller, so without modifications,

    /  the new rejoin button is only selectable by pressing right there. */

    

    /* Touch pane pointers */

    lwz r3, 0x230 + 0x174 + 0xC(r30)

    lwz r4, 0x484 + 0x174 + 0xC(r30)



    /* I could do a check here (for compatibility) instead of a direct overwrite,

    /  but I don't know what to check :/ */

    lis r5, 0x43FA

#ifdef CHECK_WW

    cmpwi r3, 0

    beq- 8

#endif

    stw r5, 0x4C(r3)

    stw r5, 0x4C(r4)



#endif /* TOUCH_PANE_PATCH */

#endif /* DRIFT_HELP_BUTTON */



    addi r4, r30, 0x94

    stw r4, 0xF34 + 0x238(r30)

    li r4, 6

    stw r4, 0xF34 + 0x240(r30)



#ifdef BMG_PATCH

#define PATCH_MID(MID) \

    li r4, MID; \

    bl get_mid_index_func; \

    li r4, BMG_STRING(mid_##MID); \

    bl overwrite_mid_func



    /* Apply the button BMG patch. MID fa5 and fa6 are normally blank, so we will use those. */

    PATCH_MID(0xFA5)

    PATCH_MID(0xFA6)



    /* Apply other misc BMG patches */

#ifndef INVISIBLE_BUTTON

    PATCH_MID(0xFB1)

#endif

    PATCH_MID(0xFB7)

    PATCH_MID(0x1009)

#endif /* BMG_PATCH */



    addi r3, r30, 0xF34

    li r4, 0xFA5

    //li r5, 0

    BL_CALL(Menu_Control_SetAllText)



    mflr r3

    addi r3, r3, button_select_data - (. - 4)

    stw r30, 0x4(r3)

    addi r4, r3, rejoin_button_press_event - button_select_data

    stw r4, 0x10(r3)

    stw r3, 0xF34 + 0x234(r30)



wifi_rejoin_button_end:

    mr r3, r30 // Original instruction

GCT_INSERT_END(wifi_rejoin_button)





/* It should only display the rejoin button if you have a room to rejoin.

   A main button disappearing would be weird, so I'd recommend only using

/  this for the DriftHelp button. */

#ifdef INVISIBLE_BUTTON

GCT_INSERT(PORT(0x806189B8, 0x8064B338, 0x8064BCCC, 0x80639FE4), set_rejoin_visibility)

    li r0, 1

    PTR_LWZ(r3, rejoin_location, 0) // Group ID

    cmpwi r3, 0

    bne+ rejoin_visible_label

    li r0, 0

rejoin_visible_label:

    stw r0, 0xF34 + 0x244(r31) // If selectable

    stw r0, 0xF34 + 0x174 + 0x70(r31) // If selectable

    xori r0, r0, 1

    stb r0, 0xF34 + 0x80(r31) // If invisible



    li r0, -1 // Original instruction

GCT_INSERT_END(set_rejoin_visibility)

#endif





/* Set back button destination for rejoin button */

GCT_INSERT(PORT(0x805E51B4, 0x806091FC, 0x80609A88, 0x805F7EA8), rejoin_back_dest)

    cmpwi r3, REJOIN

    bne- rejoin_back_dest_end



    li r0, 0x8B

    stw r0, 0x1D00(r31)



    //li r3, -1

rejoin_back_dest_end:

    li r0, 6

GCT_INSERT_END(rejoin_back_dest)





/* Set screen to go to after join failure */

GCT_INSERT(PORT(0x805E5394, 0x806093DC, 0x80609C68, 0x805F8088), rejoin_fail_dest)

    cmpwi r3, REJOIN

    bne- rejoin_fail_dest_end



    li r0, 0x8B

    stw r0, 0x1D00(r31)



    //li r3, -1

rejoin_fail_dest_end:

    li r0, 6

GCT_INSERT_END(rejoin_fail_dest)





/* Set searching text */

GCT_WRITE_32(PORT(0x805E5230, 0x80609278, 0x80609B04, 0x805F7F24), 0x60000000)

GCT_INSERT(PORT(0x805E5234, 0x8060927C, 0x80609B08, 0x805F7F28), set_rejoin_search_text)

    li r4, 0x100A

    cmpwi r0, REJOIN

    bne- not_rejoin_search_text

    

    li r4, 0x1009

    b set_rejoin_search_text_end

not_rejoin_search_text:

    cmplwi r0, 1

    BC_CALL(gt, PORT(0x805E5370, 0x806093B8, 0x80609C44, 0x805F8064))

set_rejoin_search_text_end:

GCT_INSERT_END(set_rejoin_search_text)





/* Set search failure text */

GCT_WRITE_32(PORT(0x805E45C8, 0x80608610, 0x80608E9C, 0x805F72BC), 0x60000000)

GCT_INSERT(PORT(0x805E45D4, 0x8060861C, 0x80608EA8, 0x805F72C8), set_rejoin_fail_text)

    li r4, 0xFB2

    cmpwi r0, REJOIN

    bne- not_rejoin_fail_text



    li r4, 0xFB7

    b set_rejoin_fail_text_end

not_rejoin_fail_text:

    cmplwi r0, 1

    BC_CALL(gt, PORT(0x805E4608, 0x80608650, 0x80608EDC, 0x805F72FC))

set_rejoin_fail_text_end:

GCT_INSERT_END(set_rejoin_fail_text)





/* Save location */

GCT_INSERT(PORT(0x80655C60, 0x80659754, 0x8065A0E8, 0x80648400), save_location)

    lwz r4, 0(r3) // Group ID

    cmpwi r4, 0

    beq- save_location_end



    lbz r4, 5(r3)

    cmpwi r4, 0x05

    beq- save_location_end_label

    cmpwi r4, 0x08

    bne+ save_location_end



save_location_end_label:

    lwz r4, 0(r3)

    PTR_STWU(r4, r12, rejoin_location, 0)

    lwz r4, 4(r3)

    stw r4, 4(r12)



save_location_end:

    li r4, 8

GCT_INSERT_END(save_location)





/* We no longer force regional! */

GCT_INSERT(PORT(0x8064EF10, 0x80652A04, 0x80653398, 0x806416B0), rejoin_loc_match_type)

    lwz r0, 0xE8(r3)

    cmpwi r0, REJOIN_MODE

    bne+ rejoin_loc_match_type_end



    PTR_LBZU(r4, r12, rejoin_location, 5) // Match type



    li r0, 7

    cmpwi r4, 0x05

    beq+ rejoin_loc_match_type_label

    li r0, 9



rejoin_loc_match_type_label:

    lbz r4, -1(r12) // Region ID, if anyone has ever played Regional

    cmpwi r4, 0xFF // 0xFF if Worldwide

    beq+ rejoin_loc_match_type_end

    li r0, -1 // Skip switch



rejoin_loc_match_type_end:

GCT_INSERT_END(rejoin_loc_match_type)





/* Something I spotted to patch (Is this really necessary?) */

GCT_INSERT(PORT(0x8064FEC8, 0x806539BC, 0x80654350, 0x80642668), rejoin_match_patch_1)

    lwz r0, 0xE8(r3)

    cmpwi r0, REJOIN_MODE

    bne+ 8

    li r0, 1

GCT_INSERT_END(rejoin_match_patch_1)





/* New room match mode */

GCT_INSERT(PORT(0x806532A4, 0x80656D98, 0x8065772C, 0x80645A44), rejoin_match_mode)

//.set switch_mode_end, PORT(0x8065336C, 0x80656E60, 0x806577F4, 0x80645B0C)

    cmpwi r0, REJOIN_MODE // New type: 11

    bne+ setup_normal_match

setup_rejoin_match:

    /* Join friend */

    li r0, 10



setup_normal_match:

    cmpwi r0, 1 // Original instruction

GCT_INSERT_END(rejoin_match_mode)





/* Read from rejoin status */

GCT_INSERT(PORT(0x8065523C, 0x80658D30, 0x806596C4, 0x806479DC), swap_friend_status)

    lwz r5, 0xE8(r31)

    cmpwi r5, REJOIN_MODE

    bne+ swap_friend_status_end



    PTR_LBZU(r5, r4, rejoin_location, 4)

    srwi r5, r5, 7

    xori r5, r5, 1

    lbz r6, 1(r4)

    add r3, r6, r5



swap_friend_status_end:

    cmpwi r3, 5 // Original instruction

GCT_INSERT_END(swap_friend_status)





/* Replace join group ID with our own */

GCT_INSERT(PORT(0x8065541C, 0x80658F10, 0x806598A4, 0x80647BBC), swap_group_id)

    lwz r3, 0x25EC(r3) // Normal friend group ID / Original instruction

    lwz r0, 0xE8(r31) // RKNetController->joinType

    cmpwi r0, REJOIN_MODE

    bne- swap_group_id_end



    PTR_LWZ(r3, rejoin_location, 0) // Our group ID

swap_group_id_end:

GCT_INSERT_END(swap_group_id)





/* Setup rejoin room mode */

GCT_INSERT(PORT(0x805E3CBC, 0x80607D10, 0x8060859C, 0x805F69BC), use_rejoin_room_mode)

    lwz r0, 0x1CF4(r31)

    cmpwi r0, REJOIN

    bne- use_rejoin_room_mode_end



    addi r3, r31, 0x190

    li r4, 0xFA5

    //li r5, 0

    BL_CALL(Menu_HeaderText_SetText)



    lis r29, RKNetController_sInstance@ha

    lwz r4, 0x18C(r31)

    lwz r3, RKNetController_sInstance@l(r29)

    BL_CALL(RKNetController_SetupWWVS)

    lwz r3, RKNetController_sInstance@l(r29)

    li r4, REJOIN_MODE // Rejoin room mode

    stw r4, 0xE8(r3)



    li r0, -1 // Skip switch

use_rejoin_room_mode_end:

GCT_INSERT_END(use_rejoin_room_mode)