Change Mii Name In Between Races -Online- [Vega]

Code:
#Hooked at Arg Save of OSSleepThread

#PAL    801AA9CC

#NTSC-U 801AA92C

#NTSC-J 801AA8EC

#NTSC-K 801AAD28



#Region Assembling Option

.set region, '' #Fill in E, P, J, or K within the quotes for your region when Compiling! Lowercase letters can also be used.



#EVA Notes

#800007D0 (word) is Online Self Mii Struct Ptr



#NOTE: There's NO need to make a Stack Frame because the only register that needs to be intact now is r30 and that was already saved earlier in the Hook's Func Prologue. The only non-vol register this code edits is r31, old r31 was already saved too, and new r31 gets written by game 5 sequential instructions after Hook Address. r3 doesn't need to be saved because next Hook's Child Func requires No Args.



#Directives

.if     (region == 'P' || region == 'p') #PAL

    .set USER_Static_ptr, 0x809c2108

    .set CRC16, 0x800C78D0

    .macro load_unk_ptr register

        lwz \register, -0x6968 (r13) #func 0x800bc3e0

    .endm

.elseif (region == 'E' || region == 'e') #NTSC-U

    .set USER_Static_ptr, 0x809bd958

    .set CRC16, 0x800C7830

    .macro load_unk_ptr register

        lwz \register, -0x6968 (r13) #func 0x800bc340

    .endm

.elseif (region == 'J' || region == 'j') #NTSC-J

    .set USER_Static_ptr, 0x809c1168

    .set CRC16, 0x800C77F0

    .macro load_unk_ptr register

        lwz \register, -0x6968 (r13) #func 0x800bc300

    .endm

.elseif (region == 'K' || region == 'k') #NTSC-K

    .set USER_Static_ptr, 0x809b0748

    .set CRC16, 0x800C7930

    .macro load_unk_ptr register

        lwz \register, -0x6948 (r13) #func 0x800bc440

    .endm

.else #Invalid Region

    .err #Region match not detected. Tell the Assembler to halt and throw an error.

.endif



#Original Instruction: Save r3 (only) Arg of OSSleepThread

mr r30, r3



#Load USER Packet Static Ptr. Check if we have one, and then check if a room is active

lis r12, USER_Static_ptr@ha

lwz r12, USER_Static_ptr@l (r12)

cmpwi r12, 0

beq- end

lbz r0, 0 (r12)

cmpwi r0, 0 #Will be non-null if room is active

beq- end



#Check if ZZZZ was pressed

lis r11, 0x8035 #GCN PAL used for test source

lhz r11, 0xFFFF8200 (r11) #GCN PAL used for test source

cmplwi r11, 0x0880 #GCN Y button used for test source



#Grab Online Self Mii Struct Ptr Thingy

lis r10, 0x8000

lwz r10, 0x7D0 (r10)



#Now branch for ZZZZ

beq- grab_mii_name_from_table



#Check if zzzz was pressed

cmplwi r11, 0x0480 #GCN X button used for test source

bne+ end



#Since zzzz pressed, set r11 to MiiName-4 in Mii Database

lbz r9, 0x8 (r10) #Grab Mii DB Index from Online Self Mii Struct Thingy

load_unk_ptr r11

mulli r9, r9, 74 #Each Mii Entry is 74 bytes in len

lwz r11, 0x10 (r11) #Grab Mii DB root ptr

add r11, r11, r9 #Will point to MiiData-4 because we didn't account for 4-byte RNOD Magic Header

addi r11, r11, 2 #Add 2 so we're at MiiName-4 (Mii Name starts at 0x2 offset of Mii Data)

b transfer_mii_name



#Since ZZZZ pressed set r11 to MiiName-4 in Table

grab_mii_name_from_table:

bl mii_names

.long 0x00000000 #Padding to reduce source by 1 executable instruction

.llong 0x006d006b00770069 #mkwii.com\0 used for example Mii name

.llong 0x0069002e0063006f

.long 0x006d0000

mii_names:

mflr r11



#Copy Mii Name from Table/DB to Mii Struct & USER Packet

transfer_mii_name:

li r0, 5 #5 words is 20 bytes

addi r10, r10, 0x64 #Points to Mii Name-4 in Online Self Struct

addi r31, r12, 0x10 #Need exact ptr to USER Packet Mii DATA (not name) for later CRC16 checksumming

addi r12, r12, 0xE #Points to your Mii Name-4 in USER Packet

mtctr r0

loop:

lwzu r0, 0x4 (r11)

stwu r0, 0x4 (r10)

stwu r0, 0x4 (r12)

bdnz+ loop



#Write over current Mii Checksum in USER Packet, game CRC's Mii Data with an included null checksum

li r0, 0

sth r0, 0x4A (r31)



#Setup args for CRC16 and call it

lis r12, CRC16@h

mr r3, r31

ori r12, r12, CRC16@l

li r4, 0x4C #Size of Mii Data w/ null checksum

mtctr r12

bctrl



#Write new checksum

sth r3, 0x4A (r31)



#END Code

end: