Random Character but w/ Best Bike For Every Race Online [Vega]

Code:
#C2 Hook Addresses

#NTSC-U 80612EF4

#PAL    80644314

#NTSC-J 80643980

#NTSC-K 8063262C



#Region Set

.set region, '' #Use e,p,j, or k



#Symbols

.set bullet, 0x15

.set mach, 0x16

.set flamerunner, 0x17



#Register Notes

#LR NOT safe!, r0 and r4 thru r12 safe

#r3 is SELECT Packet Ptr



#Hook Address Notes

#Code hooked at first parent that calls SELECT_Get_Winning_Track



#SELECT Packet Notes

#Relative to SELECT Handler Root Ptr which is your SELECT Ptr - 8

#Subtract offsets by 8 to get relative to actual start of your SELECT Packet

#0x8 Time of Sender

#0x10 Assumed Time of Receiver

#0x18 Your previous Race Position

#0x1A Your GP/Battle Points

#0x1C Your Character

#0x1D Your Vehicle

#0x1E Your Track Pick

#0x1F Your Rank Icon

#0x20 Your Guests previous Race Position

#0x22 Your Guests GP/Battle Points

#0x24 Your Guests Char

#0x25 Your Guests Vehicle

#0x26 Your Guests Track Pick (is yours ofc)

#0x27 Reserved/null byte

#0x28 Select ID word (unique; random)

#0x2C Battle Type (only bit 0 used of byte, rest is null/reserved)

#0x2D Team Bits (24 bits)

#0x3C Selected Track (0xFF is not picked yet)

#0x3D Selection/Lottery Phase

#0x3E Who Won Track Pick (0xFF is track not picked yet)

#0x3F CC



#Original Instruction; grab SELECT ptr

.if     (region == 'E' || region == 'e') #NTSC-U

        lwz r3, -0x26D0 (r3)

.elseif (region == 'P' || region == 'p') #PAL

        lwz r3, 0x2100 (r3)

.elseif (region == 'J' || region == 'j') #NTSC-J

        lwz r3, 0x1160 (r3)

.elseif (region == 'K' || region == 'k') #NTSC-K

        lwz r3, 0x0740 (r3)

.else #Invalid Region

        .err #Region match not detected. Tell the Assembler to halt and throw an error.

.endif



#Create Lookup Table

bl table #Values for small vehicles

.byte mach #Mario

.byte bullet #Baby Peach

.byte flamerunner #Waluigi

.byte flamerunner #Bowser

.byte bullet #Baby Daisy

.byte bullet #Dry Bones

.byte bullet #Baby Mario

.byte mach #Luigi

.byte bullet #Toad

.byte flamerunner #Donkey Kong

.byte mach #Yoshi

.byte flamerunner #Wario

.byte bullet #Baby Luigi

.byte bullet #Toadette

.byte bullet #koopa

.byte mach #Daisy

.byte mach #Peach

.byte mach #Birdo

.byte mach #Diddy Kong

.byte flamerunner #King Boo

.byte mach #Bowser Jr

.byte flamerunner #Dry Bowser

.byte flamerunner #Funky Kong

.byte flamerunner #Rosalina

.align 2



table:

mflr r12



#Grab Character Value from EVA

lis r11, 0x8000

lbz r10, 0x4C0 (r11)



#Based on Character value, grab its best vehicle

lbzx r9, r10, r12



#Write Character+Vehicle to SELECT packet

stb r10, 0x1C (r3)

stb r9, 0x1D (r3)