Random Character+Vehicle For Every Race -Online- [Vega]

Code:
#C2 Hook Addresses

#NTSC-U 80612EF4

#PAL    80644314

#NTSC-J 80643980

#NTSC-K 8063262C



#Region Set

.set region, '' #Use e,p,j, or k



#Register Notes

#LR safe

#r3 is SELECT Packet Ptr



#Hook Address Notes

#Code hooked at first parent that calls SELECT_Get_Winning_Track



#SELECT Packet Notes

#Relative to SELECT Handler Root Ptr which is your SELECT Ptr - 8

#Subtract offsets by 8 to get relative to actual start of your SELECT Packet

#0x8 Time of Sender

#0x10 Assumed Time of Receiver

#0x18 Your previous Race Position

#0x1A Your GP/Battle Points

#0x1C Your Character

#0x1D Your Vehicle

#0x1E Your Track Pick

#0x1F Your Rank Icon

#0x20 Your Guests previous Race Position

#0x22 Your Guests GP/Battle Points

#0x24 Your Guests Char

#0x25 Your Guests Vehicle

#0x26 Your Guests Track Pick (is yours ofc)

#0x27 Reserved/null byte

#0x28 Select ID word (unique; random)

#0x2C Battle Type (only bit 0 used of byte, rest is null/reserved)

#0x2D Team Bits (24 bits)

#0x3C Selected Track (0xFF is not picked yet)

#0x3D Selection/Lottery Phase

#0x3E Who Won Track Pick (0xFF is track not picked yet)

#0x3F CC



#Original Instruction; grab SELECT ptr

.if     (region == 'E' || region == 'e') #NTSC-U

        lwz r3, -0x26D0 (r3)

.elseif (region == 'P' || region == 'p') #PAL

        lwz r3, 0x2100 (r3)

.elseif (region == 'J' || region == 'j') #NTSC-J

        lwz r3, 0x1160 (r3)

.elseif (region == 'K' || region == 'k') #NTSC-K

        lwz r3, 0x0740 (r3)

.else #Invalid Region

        .err #Region match not detected. Tell the Assembler to halt and throw an error.

.endif



#Create Lookup Table

bl table #Index 0; Values for small vehicles

small_table:

.byte 0

.byte 3

.byte 6

.byte 9

.byte 0xC

.byte 0xF

.byte 0x12

.byte 0x15

.byte 0x18

.byte 0x1B

.byte 0x1E

.byte 0x21

medium_table: #Index 12; Values for medium vehicles

.byte 1

.byte 4

.byte 7

.byte 0xA

.byte 0xD

.byte 0x10

.byte 0x13

.byte 0x16

.byte 0x19

.byte 0x1C

.byte 0x1F

.byte 0x22

large_table: #Index 24; Values for large vehicles

.byte 2

.byte 5

.byte 8

.byte 0xB

.byte 0xE

.byte 0x11

.byte 0x14

.byte 0x17

.byte 0x1A

.byte 0x1D

.byte 0x20

.byte 0x23

table_index_values:

.byte 12 #Mario

.byte 0 #Baby Peach

.byte 24 #Waluigi

.byte 24 #Bowser

.byte 0 #Baby Daisy

.byte 0 #Dry Bones

.byte 0 #Baby Mario

.byte 12 #Luigi

.byte 0 #Toad

.byte 24 #Donkey Kong

.byte 12 #Yoshi

.byte 24 #Wario

.byte 0 #Baby Luigi

.byte 0 #Toadette

.byte 0 #koopa

.byte 12 #Daisy

.byte 12 #Peach

.byte 12 #Birdo

.byte 12 #Diddy Kong

.byte 24 #King Boo

.byte 12 #Bowser Jr

.byte 24 #Dry Bowser

.byte 24 #Funky Kong

.byte 24 #Rosalina

.align 2

table:

mflr r12



#Grab Random Value 1 (char) and 2 (veh) from EVA

lis r11, 0x8000

lbz r10, 0x4C0 (r11)

lbz r11, 0x4C1 (r11)



#Set a ptr to table_index_values, and then based on random value 1, grab characters 0/12/24 value

addi r9, r12, 36

lbzx r8, r10, r9



#Now set adjust the Root Table ptr to within the table based on r8's value (r8 will be 0, 12, or 24)

add r12, r12, r8



#Grab vehicle using new r12 ptr and random value 2

lbzx r8, r12, r11



#Write Char+Vehicle to SELECT packet

stb r10, 0x1C (r3)

stb r8, 0x1D (r3)