More Stuff

So far we've only worked in Programs that is just one Source File. What if your Program is too large for one File? How do we include other files? When the Source File in question is a "pure" assembly file (lowercase "s" extension), you will use the following Assembler Directive to include another File...

Here's an example below. The first code snippet is the central Source File. Its name is start.s. The second code snippet is the Program's second File with the name power.s. The power.s file resides in a folder called "Functions" which resides adjacent to the start.s file. Program Layout is so...

The power.s file contains a function that we've named "power". Whenever you are using labels across files, you need to use the ".globl" directive or else the Linker won't know how to "link" together the functions/branches. Assembling would still be the same...

You can apply this same concept to Assembly files that get processed thru the C compiler (uppercase "S" extension). The include directive would be that of what you would find in any standard C program...

Your included file(s) can be .s or .S. If your included files are using C functions, be sure to use the uppercase S. Here's the same program as above, but assembling to include C functions.

#include "Functions/power.s"
    .globl main
main:
...
...
...

Since this Program is going thru the C compiler, the central Source File has to be named main.S. Any other name will cause the C compiler to refuse to compile the program.

Section 2: Conditional Assembling

You may need to write a Program where certain blocks of code are to only be assembled based on certain inputs of the terminal command used when Assembling.

#Code below is conditional and will only assemble when given the proper terminal inputs in the GNU Assembler
.ifdef CodeBlock1
    add r14, r15, r16
    li r20, 0
    stw r8, -0x4 (r4)
.endif

#Code below is conditional and will only assemble when given the proper terminal inputs in the GNU Assembler
.ifdef CodeBlock2
    add r22, r15, r16
    li r20, 1
    stw r8, 0 (r4)
.endif

#Code below is unconditional and will always be assembled
lis r12, 0x8000
rlwinm r0, r3, 0, 24, 31

The terms conditional and unconditional have nothing to do with branches. They only pertain with the parts of the program that will be Assembled.

"CodeBlock1" and "CodeBlock2" are custom names (labels/symbols). When assembling the above Project (file name will be cond_example.s), you would tell the Assembler to include assembling CodeBlock1 by doing this..

You can instead you numbers using one name for the Assembler Directives instead a different names like this..

#Code below is conditional and will only assemble when given the proper terminal inputs in the GNU Assembler
.if CondCode == 4
    add r14, r15, r16
    li r20, 0
    stw r8, -0x4 (r4)
.endif

#Code below is conditional and will only assemble when given the proper terminal inputs in the GNU Assembler
.if CondCode == 5
    add r22, r15, r16
    li r20, 1
    stw r8, 0 (r4)
.endif

#Code below is unconditional and will always be assembled
lis r12, 0x8000
rlwinm r0, r3, 0, 24, 31

The above would assemble the first CondCode block while omitting the second. If you want to assemble the second block instead, you would replace 4 with 5. Of course, if you put something other than 4/5, the Assembler will reject it and output an error message.

#Code below is conditional and will only assemble when given the proper terminal inputs in the GNU Assembler
.if CondCode == 1
    add r14, r15, r16
    li r20, 0
    stw r8, -0x4 (r4)
.else
    add r22, r15, r16
    li r20, 1
    stw r8, 0 (r4)
.endif

#Code below is unconditional and will always be assembled
lis r12, 0x8000
rlwinm r0, r3, 0, 24, 31

Section 3: Some common instructions we haven't covered yet

Let's say you are working on a project that stores a Signed Halfword (halfword value that can possibly be negative), and you need to load it back at a later point in your project. The beginner would write something like this...

#Store signed halfword to reserved memory spot. Use 32-bits because negative halfwords are 32-bits in length
stw rX, 0xZZZZ (rY)
...
...
...
#Load signed halfword
lwz rX, 0xZZZZ (rY)

This is a waste of memory and you don't need to do this. You can use the lha (load halfword algebraic) instruction instead...

#Store signed halfword, but only its lower 16 bits.
sth rX, 0xZZZZ (rY)
...
...
...
#Load halfword and sign extend it.
lha rX, 0xZZZZ (rY)

How lha works~
When the value is loaded into the Register, bit 16's value is copied to all bits of 0 thru 15. In simpler terms, if the value loaded is 0x8000 thru 0xFFFF, then it is prepended with 0xFFFF.

Examples:
0x5678 loads as 0x00005678
0xFFFE loads as 0xFFFFFFFE
0x809C loads as 0xFFFF809C
0x0000 loads as 0x00000000
0x7F00 loads as 0x00007F00

If you are working with signed Bytes, we have to switch some things up as PowerPC does *NOT* have a "lba" instruction. You would need to the following when loading a byte that is to be treated as Signed.

#Example. Load signed byte into r5 from r10+0x2100
lbz r5, 0x2100 (r10)
extsb r5, r5

extsb stands for Extend Sign Byte. In technical terms, bit 24's value is copied to all bits of 0 thru 23. In simpler terms, if the value is 0x80 thru 0xFF, then it is prepended with 0xFFFFFF. exstb also has the ability to use the record feature (exstb. rD, rA). That way you can sign extend a byte and compare it to 0 at the same time.

Section 4: Int to Float Conversions

It's rare but you may run into a situation where you need to convert an Integer to a Float. There are no dedicated single PPC instructions for this. It has to be done "by hand: Here are two snippets of example code. They both take r3's value, convert it to a float, then write the result to f1. First code treats r3 as signed, second code treats r3 as unsigned. Both codes assume r4 is a spot to some allocated memory and that r4's address is divisible by 4 (so Alignment exception won't occur).

#r3 = GPR to convert to float
#r4 = pointer to some allocated memory of at least 8 bytes that is word-aligned
#f1 = Where float result goes

#Write unique Double Float "Magic"
lis r5, 0x4330
lis r6, 0x8000

#Store Double Float "Magic" to allocated memory
stw r5, 0 (r4)
stw r6, 0x4 (r4)

#Flip sign bit of Integer
xoris r3, r3, 0x8000

#Load Double Float "Magic" into FPR 2
lfd f2, 0 (r4)

#Store Integer as Lower Half of Temp Float with using Magic upper
stw r3, 0x4 (r4)

#Load Whole Temp Double Float, subtract with Magic to get Result
lfd f1, 0 (r4)
fsub f1, f1, f2 #Result is in 64-bit Single Precision form

#r3 = GPR to convert (as unsigned) to float
#r4 = pointer of some allocated memory of at least 8 bytes
#f1 = Where float result goes

#Write unique Double Float "Magic"
lis r5, 0x4330
li r6, 0

#Store Double Float "Magic" to allocated memory
stw r5, 0 (r4)
stw r6, 0x4 (r4)

#Load Double Float "Magic" into FPR 2
lfd f2, 0 (r4)

#Store Integer as Lower Half of Temp Float with using Magic upper
stw r3, 0x4 (r4)

#Load Whole Temp Double Float, subtract with Magic to get Result
lfd f1, 0 (r4)
fsub f1, f1, f2 #Result is in 64-bit Single Precision form

PowerPC Tutorial

Section 1: Including other files in your Program

Section 2: Conditional Assembling

Section 3: Some common instructions we haven't covered yet

Section 4: Int to Float Conversions