Instant Transmission [Vega]

Remember Goku's Instant Tranmission technique? Well now you can mimic it with any character in the game! This code is a teleportation code. Press desired button(s) on your controller to save (and later update if needed) your current XYZ position/coordinates. Then press a secondary button(s) on your controller any time later to instantly teleport to the saved XYZ position/coordinates.

Also, you can choose to apply this code to 1P or 2P/COM.

S = Slot (0 = 1P; 1 = 2P/COM)
XXXX = Controller Address
ZZZZ = Button to save XYZ
zzzz = Button to teleport to saved XYZ

Link to X & Z values - https://mariokartwii.com/nonmkwcodes/dbzbt3/bt3gecko.txt

NTSC-U
C204539C 0000000B
83FE000C 2C1F000S
40820048 3FE0803B
A3FFXXXX 3C808000
38A30970 2C1FZZZZ
40820018 E0050000
C0250008 F00407E0
D02407E8 4800001C
2C1Fzzzz 40820014
E00407E0 C02407E8
F0050000 D0250008
7C7F1B78 00000000

Code creator: Vega

Source~

#START ASSEMBLY

#Address
#NTSC-U = 8004539C

#Address Hook Notes
#Hook address alternates between 1P & 2P/COM. Address resides in function call which has the child function of 0x80009244 which is used to load and update the modifiable XYZ coordinates. The call to 0x80009244 is the first memory (read or write) BP to be hit after manually modifying the XYZ coords after a Dolphin emulation pause. Essentially best hook address w/o having to 'deep-dive' too much, lol. Fyi 0x80009244 does a load on the modifiable XYZ coords, then stores them to MasterPointer + 0x10.

#Register Notes
#r30 is always Master Pointer
#GVRs do some swapping content shit so we can't rely on them for slot values, but we can get slot value just by loading word at MP + 0xC.
#r4, & r5 safe for use
#r31 safe for use before original instruction
#f0 & f1 safe for use

#Check User slot
lwz r31, 0xC (r30)
cmpwi r31, 0
bne- original_instruction

#Set Controller Upper Half
lis r31, 0x803B

#Load Controller Button Halfword Value
lhz r31, 0x0E20 (r31) #GCN controller used for compilation, adjust this accordingly

#Set EVA Upper Half
lis r4, 0x8000

#Set XYZMemPointer (simply add 0x970 to r3)
addi r5, r3, 0x0970

#Check if Save Button was pressed
cmpwi r31, 0x0008 #GCN Up Button used for compilation, adjust this accordingly
bne- check_tele_button

#Save button was pressed, load real XYZ Coordinates and write them to EVA
psq_l f0, 0 (r5), 0, 0
lfs f1, 0x8 (r5)
psq_st f0, 0x07E0 (r4), 0, 0
stfs f1, 0x07E8 (r4)
b original_instruction

#Check if Teleport Button was pressed
check_tele_button:
cmpwi r31, 0x0004 #GCN Down Button used for compilation, adjust this accordingly
bne- original_instruction

#Teleport button was pressed, load EVA Coordinates and write them to real XYZ Space
psq_l f0, 0x07E0 (r4), 0, 0
lfs f1,0x07E8 (r4)
psq_st f0, 0 (r5), 0, 0
stfs f1, 0x8 (r5)

#Original Instruction; backup r3 return value to r31 from just calling GetGeometryPointer
original_instruction:
mr r31, r3